Notes IconHave a read of this help topic to get a basic understanding of what is involved with advanced customization.

Introduction

All of the Workbook-S-140 templates support the Memorial event on your schedule. They are designed to complement the look and feel of default Workbook S-140 schedule.

Feel free to copy the template and customize it as you see fit and from herein it is assumed that you are already familiar with advanced customization.

Quick Navigation


Underlying XML

The Memorial event is included in the underlying XML file using the following syntax.

Notes IconLong lines have been word-wrapped for ease of reading.

<SpecialEvent>
    <Event>Memorial</Event>
    <Location>Locate of Memorial</Location>
    <Date Day="4" 
          DayShort="Tue" 
          DayFull="Tuesday" 
          Month="4" 
          MonthShort="Apr" 
          MonthFull="April" 
          Year="2023" 
          Memorial="1" 
          AllDayEvent="0" 
          StartTime12="7:00" 
          StartTime24="19:00" 
          EndTime12="7:55" 
          EndTime24="19:55" MidweekEvent="1">04/04/2023</Date>
    <MemorialInfo>
        <SongOpen Title="A Special Possession" 
                   StartTime12="7:00" 
                   StartTime24="19:00" 
                   EndTime12="7:05" EndTime24="19:05" DurationShort="5 min.">25</SongOpen>
        <VideoConferenceHost>Name 1</VideoConferenceHost>
        <VideoConferenceCohost>Name 2</VideoConferenceCohost>
        <ZoomAttendant>Name 3</ZoomAttendant>
        <Chairman>Name 4</Chairman>
        <PrayerOpen>Name 5</PrayerOpen>
        <PrayerEnd>Name 6</PrayerEnd>
        <Speaker StartTime12="7:05" 
                  StartTime24="19:05" 
                  EndTime12="7:50" 
                  EndTime24="19:50" DurationShort="45 min.">Name 7</Speaker>
        <Theme>Appreciate What God and Christ Have Done for You!</Theme>
        <SongEnd Title="Grateful for the Ransom" 
                  StartTime12="7:50" 
                  StartTime24="19:50" 
                  EndTime12="7:55" 
                  EndTime24="19:55" DurationShort="5 min.">18</SongEnd>
        <ImagePath>D:\Memorial\Sample Image.jpg</ImagePath>
        <ImageWidthPercent>80</ImageWidthPercent>
        <TextBeforeImage>Text before</TextBeforeImage>
        <TextAfterImage>Text after</TextAfterImage>
    </MemorialInfo>
</SpecialEvent>

Memorial Info

Use this template to display the Memorial on your schedule. Please note the following:

  • The special event Description is used as the Heading.

<xsl:template match="MemorialInfo">
       <table class="tableMemorial">
               <colgroup>
                       <col class="columnTime"/>
                       <col class="columnPublicTalk"/>
                       <col class="columnName"/>
               </colgroup>
               <!-- Row: Heading -->
               <tr>
                       <td class="cellMemorial" colspan="3">
                               <div class="textMemorialHeading">
                                       <xsl:value-of select="../Event"/>
                               </div>
                       </td>
               </tr>
               <!-- Date and Chairman -->
               <tr>
                       <td class="cellMemorial" colspan="2">
                               <div class="textMemorialDate">
                                       <xsl:value-of select="../Date/@DayFull"/>
                                       <xsl:text> </xsl:text>
                                       <xsl:value-of select="../Date/@Day"/>
                                       <xsl:text> | </xsl:text>
                                       <xsl:value-of select="../Date/@MonthFull"/>
                               </div>
                               <div class="floatRight textHeadingLabel">
                                       <xsl:value-of select="//Labels/PTS_Chairman"/>
                               </div>
                       </td>
                       <td class="cellName">
                               <xsl:value-of select="Chairman"/>
                       </td>
               </tr>
               <!-- Row: Audio Visual Team (if all names are provided) -->
               <xsl:if test="VideoConferenceHost != '' and VideoConferenceCohost != '' and ZoomAttendant != ''">
                       <tr>
                               <td colspan="2">
                                       <div class="floatRight">
                                               <xsl:value-of select="//Labels/VideoConferenceHost"/>
                                               <br/>
                                               <xsl:value-of select="//Labels/VideoConferenceCohost"/>
                                               <br/>
                                               <xsl:value-of select="//Labels/ZoomAttendant"/>
                                       </div>
                               </td>
                               <td class="cellName">
                                       <xsl:apply-templates select="VideoConferenceHost"/>
                                       <br/>
                                       <xsl:apply-templates select="VideoConferenceCohost"/>
                                       <br/>
                                       <xsl:apply-templates select="ZoomAttendant"/>
                               </td>
                       </tr>
               </xsl:if>
               <!-- Row: Opening Song and Opening Prayer -->
               <tr>
                       <xsl:apply-templates select="SongOpen" mode="Memorial"/>
                       <xsl:apply-templates select="PrayerOpen" />
               </tr>
               <!-- Row: Memorial Theme and Speaker -->
               <tr>
                       <td class="cellTime">
                               <xsl:value-of select="Speaker/@EndTime24"/>
                       </td>
                       <td class="cellTheme">
                               <span class="bulletMI">
                                       <xsl:text>&#8226;</xsl:text>
                               </span>
                               <span class="textPTSLabel">
                                       <xsl:value-of select="//Labels/PTS_Theme"/>:
                               </span>
                               <xsl:text> </xsl:text>
                               <span class="textPTSValue">
                                       <xsl:value-of select="Theme"/>
                               </span>
                               <div class="floatRight">
                                       <xsl:value-of select="//Labels/PTS_Speaker"/>:
                               </div>
                       </td>
                       <td class="cellName">
                               <xsl:value-of select="Speaker"/>
                       </td>
               </tr>
               <!-- Row: Closing Song and Closing Prayer -->
               <tr>
                       <xsl:apply-templates select="SongEnd" mode="Memorial" />
                       <xsl:apply-templates select="PrayerEnd" />
               </tr>
               <!-- Location, Image and Notes -->
               <tr>
                       <td colspan="3" class="memorial-container">
                               <p class="memorial-location">
                                       <xsl:value-of select="../Location"/>
                               </p>
                               <p class="memorial-textbefore">
                                       <xsl:value-of select="TextBeforeImage" disable-output-escaping="yes"/>
                               </p>
                               <img class="memorial-image">
                                       <xsl:attribute name="src">
                                               <xsl:value-of select="ImagePath"/>
                                       </xsl:attribute>
                                       <xsl:attribute name="width">
                                               <xsl:value-of select="ImageWidthPercent"/>
                                               <xsl:text>%</xsl:text>
                                       </xsl:attribute>
                                       <xsl:attribute name="alt">
                                               <xsl:text>Memorial Image</xsl:text>
                                       </xsl:attribute>
                               </img>
                               <p class="memorial-textafter">
                                       <xsl:value-of select="TextAfterImage" disable-output-escaping="yes"/>
                               </p>
                       </td>
               </tr>
       </table>
</xsl:template>

Adjust your template to display the Memorial as follows. Note that you will need to cater for both the Midweek and Weekend.

Notes IconThe sample below has been extracted from the Workbook-S-140 template.

<xsl:choose>
       <xsl:when test="@SpecialEvent=1 and SpecialEvent/Date/@Memorial=1 and SpecialEvent/Date/@MidweekEvent=1">
               <!-- Midweek Memorial -->
               <xsl:apply-templates select="SpecialEvent/MemorialInfo"/>
       </xsl:when>
       <xsl:otherwise>
               <!-- The WEEK template will conditionally display any Special Event (if appropriate) -->
               <xsl:call-template name="WEEK"/>

               <!-- The TFGW | AYFM | LAC elements only exist if there is a valid Midweek Meeting. -->
               <xsl:apply-templates select="TFGW"/>
               <xsl:apply-templates select="AYFM"/>
               <xsl:apply-templates select="LAC"/>
       </xsl:otherwise>
</xsl:choose>

<!-- Weekend Memorial -->
<xsl:if test="@SpecialEvent=1 and SpecialEvent/Date/@Memorial=1 and SpecialEvent/Date/@MidweekEvent=0">
       <!-- Weekend Memorial -->
       <xsl:apply-templates select="SpecialEvent/MemorialInfo"/>
</xsl:if>

An extra clause was added to the test.

Song Titles

Use this template to display the two song numbers on the schedule.

<!--Displays the song information for Memorial Event -->
<xsl:template match="SongOpen | SongEnd" mode="Memorial">
       <td class="cellTime">
               <xsl:value-of select="@EndTime24"/>
       </td>
       <td class="cellTheme">
               <xsl:if test=". != 0">
                       <span class="bulletMI">
                               <xsl:text>&#8226;</xsl:text>
                       </span>
                       <span class="textSongLabel">
                               <xsl:value-of select="//Labels/Song"/>
                       </span>
                       <span class="textSongNumber">
                               <xsl:value-of select="."/>
                       </span>
                       <span class="textSongTitle">
                               <xsl:value-of select="@Title"/>
                       </span>
               </xsl:if>
               <div class="floatRight">
                       <xsl:value-of select="//Labels/Prayer"/>
               </div>
       </td>
</xsl:template>

Notes IconThe song information is not displayed when the song number has a value of 0. This value represents the first (blank) item in the drop-down list of song titles on the Memorial window.

Stylesheet Classes

These classes have been provided for you to customize how the information is displayed. These can be found towards the end of the stylesheet:

.tableMemorial {
    margin-bottom: 2mm;
}

.textMemorialHeading {
    padding: 1mm;
    color: #fff;
    background-color: #FD00FF;
    width: 90mm;
    font-size: 12pt;
    font-weight: 700;
    text-transform: uppercase;
    vertical-align: middle;
}

.textMemorialDate {
    padding-left: 1mm;
    float: left;
    text-transform: uppercase;
    font-size: 11pt;
    font-weight: 700;
}

.bulletMI {
    padding-right: 1mm;
    color: #FD00FF;
    font-weight: normal;
}

.memorial-container {
    text-align: center;
}

.memorial-location {
}

.memorial-textbefore {
}

.memorial-textafter {
}

.memorial-image {
}

.cellMemorial {
    padding-left: 1mm;

The tableMemorial class needs to be added to the print section of the CSS file too:

@media print {
    body {
        background: #FFF;
    }

    .containerPage, .containerMeeting, .tableDATE, .tableHEADING, .tableTFGW, .tableAYFM, .tableLAC, .tableWeekend, .tableMemorial {
        width: 99%;
        min-width: 99%;
        max-width: 99%;
        padding-left: 0;
        padding-right: 0;
        margin-left: auto;
        margin-right: auto;
    }
}